Обзор

• Ejick (Electronic Journal Information Communications Knots -- Узлы информационных коммуникаций электронного журнала): система, позволяющая вести электронный учет различных физических параметров.

• Изначально сайт создавался для контроля и управления состоянием теплицы, со временем разросся до полноценной платформы IOT, так как возникла потребность контроля параметров любых объектов из любой точки мира.

• Сайт предназначен для обучения и развития IoT (интернета вещей). От пользователя ожидается наличие желания "посмотреть в Интернете". Система построена таким образом, чтобы минимизировать порог входа в мир IOT. Конечно, пользователю необходимо знать элементарные приёмы программирования и базовые знания об основном языке - С. При этом мы постарались упростить процесс подключения до того минимума, чтобы смог разобраться даже школьник ;)

• Данные на сайт передаются посредством POST запросов по протоколу HTTP или пакетов по протоколу MQTT и хранятся для дальнейшей обработки пользователем или просмотра архивов. Доступно создание из архивов элементарной статистики и сохранение данных пользователю в файл Excel в формате *.xlsx для дальнейшего анализа.

• Если микроконтроллер подключен по протоколу MQTT, существует возможность удаленно управлять устройствами в режиме реального времени. Эта функция не будет документирована и не рекомендуется к использованию в связи с уязвимостью Wi-Fi. Полный доступ возможен только в локальных версиях Ejick, начиная с v.2.10.local.

• Хотя это и не является ограничением, мы рекомендуем в своих проектах по возможности заменять проводное соединение на Wi-Fi. Вплоть до установки ретранслятора. Конечно, Wi-Fi менее отказоустойчивая связь, но обилие проводов также не украшает проект

• Параметры измеряются и передаются микроконтроллерами (шилдами) любого типа, имеющими выход в Сеть. Мы рекомендуем микроконтроллеры на базе ESP8266 ввиду их простоты и дешевизны. К примеру, ejick также может общаться с Arduino или Raspberry, но они явно дороже, а Raspberry, кроме того, еще и намного сложнее. Но, на вкус и цвет, как говорится...

• Для подключения к Ejick, Вам достаточно иметь шилд с датчиком и базовые знания о прошивке в среде Arduino IDE.

• Измеряемые параметры могут быть любые, например:
  • температура;
  • давление;
  • состояние (вкл/выкл);
  • сила света, количество фотонов, прочие виды излучений;
  • измерение расстояний, например, уровень зерна в ёмкости;
  • различные счётчики и измерители(напряжения, тока, импульсов, движения, ускорения и т.п.);

  • любые прочие параметры, которые можно оцифровать, прочитать и записать.

• Область применения:
  • Обучение IOT "с нуля";
  • Домашнее хозяйство: метеостанции, управление бытовыми приборами или техникой;
  • Теплицы, котельные, мелкое производство;
  • Охранные и контролирующие системы, учёт изменений состояния объекта, ведение журнала доступа и т.п.;

  • Сельское, коммунальное хозяйство: учёт, контроль и оптимизация процессов. Например, качество(состав) воды, давление в водопроводе, количество осадков и пр.

• Дополнительную информацию можно найти в Сети по запросу "ESP8266: отправка данных на сайт методом POST запроса".

Условия

• Сайт предоставляет услуги по принципу "как есть".

• По умолчанию на Главной странице незарегистрированный пользователь увидит, как примерно будут выглядеть его данные. После регистрации страница предоставит данные Юзера.

• Публичный код может быть предоставлен любому юзеру собственником аккаунта. При этом "гость" получает доступ к просмотру данных через Диспетчер, не имея возможности просматривать архивы и изменять настройки шилдов. Если у Вас есть чей-то публичный код, Вы можете его указать вместо входа или регистрации. Функция предназначена для передачи прав наблюдения за процессами третьим лицам, например наёмному персоналу.

• Старайтесь в передаваемой информации не указывать адреса, ФИО и другие личные данные.

• Измеряемые параметры передаются в POST запросе вида "Ваш логин?ID датчика?Пароль датчика?Значение" или пакет MQTT вида "ID датчика?Ваш логин?Значение". Более подробное описание Вы найдёте в примерах прошивок ниже.

• Опорная единица времени: 1 минута. Поэтому допускается запись на сервер не чаще, чем раз в минуту. Как правило, для бытовых нужд достаточно раз в 10 минут или реже.

• Обратите внимание: для корректной работы системы оповещения о проблемах с шилдом(в частности, о потере связи), убедитесь, что время в браузере синхронизировано и показывает точное время с учётом текущего пояса. При установленной автосинхронизации, как правило, ничего делать дополнительно не требуется.

• При неактивности датчика в течение календарного месяца, он может быть удален.

• При нарушении данных условий, в частности, неадекватной активности или при неактивности аккаунта в течение календарного месяца, аккаунт может быть удален. Администрация не следит и не запоминает Ваши данные, поэтому процедура удаления не может быть отменена и аккаунт удаляется без возможности восстановления. Давайте жить дружно!

Подключение

• Зарегистрироваться.

• Логин->добавить контроллер.

• Настроить при необходимости

• Прошить контроллер

• Смотреть :)

Разделы

Главная страница

• Состояние*. Может быть несколько вариантов:

"Обновлено", чёрный: Контроллер пишет, данные из кэша.

"Ожидание" или ?, чёрный: Кэш пустой - датчик недавно подключён или не присылал данные больше "Warning" времени(Настройки->Warning).

"Обновлено", зелёный: Текущие данные обновлены, контроллер на связи.

Время, оранж: Время последних записанных данных, прошло более "Warning" времени(Настройки->Warning).

Дата_Время, красный: Дата и время последних записанных данных, прошло более "Danger" времени(Настройки->Danger). Если показания данного шилда для Вас перестали быть актуальны, просто удалите его. Внимание: данные из архива также будут удалены! Если Вы хотите сохранить архивы, установите: Не показывать датчик(Настройки->Показывать?)

*В некоторых случаях, если сам браузер потерял связь, достаточно просто перегрузить страницу. Обязательно проверьте время самого браузера! В некотроых мобильных усройствах даже синхронизированное время не совпадает со всемирным координированным временем, по которому живёт ejick.

• Данные обновляются автоматически, графики перерисовываются

• Практически все видимые элементы, в т.ч. глубина данных графиков (не более суток) устанавливаются в Меню: Контроллеры->Настройки

Настройки

Здесь можно установить следующие параметры: *

• Название устройства.
• Пароль устройства, необходим для аутентификации контроллера при подключении к серверу (допускаются только символы латиницы и цифры).
• Единица измерения. Для шкалы ординат графиков.
• Описание устройства. Для заглавия графиков.
• Округлять. Данные, которые присылает шилд, могут быть любыми. Для отображения их в удобном виде, ejick попытается их округить до заданного значения знаков после запятой.
• Система контроля обратной связи

Warning. Время, мин. Если в течение этого времени контроллер не прислал данные, будет выведено сообщение об ошибке "warning"'. Первое сообщение об ошибке. Перехватывается, если контроллер пропустил запись 1-2 раза. Рекомендуется 1-30 мин. Допустимый диапазон: 1-60 минут

Danger. Время, мин. Если в течение этого времени контроллер не прислал данные, будет выведено сообщение об ошибке "danger". Второе сообщение об ошибке. Перехватывается, если контроллер давно не появлялся на связи. Рекомендуется 10-600 мин. Допустимый диапазон: 10-1440 минут

Естественно, при настройке этих параметров, Warning должно быть меньше Danger.

• Показывать контроллер. Если Вы хотите, чтобы запись шла, но на главной не отображался контроллер, выключите позицию. Показания также исчезнут из раздела "Только данные".
• Цвет линии.
• Глубина. На график выводится массив точек, ограниченный количеством минут. Максимальное значение: 1440.
• Тема. Цвет фона графика.

*При изменении, настройки каждого контроллера необходимо сохранять индивидуально.

Только данные

• Это минимализированная главная страница. Убраны графики, описание. Данные предоставлены только числами.
• Здесь можно свернуть браузер до минимального размера и расположить поверх других окон. Таким образом можно, например, параллельно мониторить камеры наблюдения и т.п.
• Добавляется возможность управления шилдом. Если он, конечно, прошит для обмена сообщениями по протоколу MQTT.

• Управление предоставлено тремя командами: "меньше", "больше", "вкл/выкл". Таким образом, со стороны шилда можно принимать и обрабатывать не менее трёх событий и больше. Три события включены в скетч по умолчанию, если надо больше, необходимо изменить логику обработки событий на уровне Вашего устройства.

Публичный ключ

• Страница позволяет создать или отредактировать публичный ключ, чтобы Ваши данные были видны другим людям.
• Ключ может быть указан незарегистрированным пользователем в разделе "ввести код".
• Ключ определяет права доступа к Вашим данным. Анонимный юзер, получив код, может просматривать показания контроллеров от Вашего имени. Он не будет иметь возможность настраивать шилды. Также ему будут недоступны архивы.
• Ключ, например, может быть предоставлен операторам котельной для мониторинга производственной ситуации.
• Ключ не даёт права управления шилдами из соображений безопаснтсти. Управлять можно только от имени собственника аккаунта.
• Если Вы не планируете пользоваться ключом, удалите его и сохраните пустое поле. Вы всегда можете изменить свой выбор, в том числе, если подозреваете, что ключ был скомпроментирован.

Базовый HTTP

• Демонстрационный пример предназначен для работы ESP8266 (Nodemcu v3) с иммитацией датчика температуры. В примере шилд передаёт время своей работы (millis()). Замените на свои параметры. Подключение проверено на Arduino IDE 1.8.18, менеджер плат: Arduino core for ESP8266 WiFi chip v.3.0.2.

• Скопируйте в Вашу IDE и замените своими данными следующие переменные:
• ssid
• password
• ID (Настройки -> ID контроллера)
• User (Ваш логин)

• Pas (Настройки -> Пароль)

---------------------------->

#include <ESP8266HTTPClient.h>
#include <ESP8266WiFi.h>

WiFiClient client;

const char* ssid = "Name_WiFi";                   //Имя Вашего WiFi
const char* password = "Password_WiFi";           //Пароль WiFi
String Query = "http://ejick.ru/add/";            //Адрес запроса, не менять
String ID = "ID_Shield";                          //Системный ID контроллера, см. Настройки -> ID контроллера
const char* User = "UserName";                    //Ваш логин на ejick.ru
const char* Pas = "PasswordShield";               //Ваш пароль от контроллера, см. Настройки -> Пароль
const byte Second = 60;                           //Период отправки, секунд, должно быть не менее минуты
uint32_t myTimer1 = 0;
uint32_t period = 0;

void connectWiFi(){                               //Подключение к сети
  Serial.println("Connecting to WiFi");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.println (millis());
  }
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void ejick(String User, String ID, String Pas, String Value) {
  byte k = 0;
  int a = 0;
  int b = 0;
  String message = "";
  HTTPClient http;                                //Объявить объект класса HttpClient
  http.begin(client, Query);                      //Устанавливаем ссылку
  delay(500);  
  http.addHeader("Content-Type", "text/plain");   //3аголовок типа содержимого
  String s = User;                                //Собираем тело запроса
  s += F("?");
  s += Pas;
  s += F("?");
  s += Value;                                       
  message = ID + "?";                             //Готовим сообщение к передаче
  for (int i = 0; i < s.length(); i++) {
    a = (int) s[i];
    b = (int) Pas[k];
    if(i != 0) message +=  ":";
    message += String(a + b, HEX);
    k++;
    if (k == Pas.length()) k = 0;
  };
  Serial.print("message");
  Serial.println(message);
  int httpCode = http.POST(message);              //Публикуем...
  String payload = http.getString();              //Ответ сервера 
  Serial.printf("Код ответа: %d\n", httpCode);    //Разбираем ответ...
  if (httpCode > 0) {
    Serial.print("Ответ сервера: <<");
    Serial.print(payload);
    Serial.println(">>");
    Serial.println();
  } else {
    Serial.println("Настройки не позволяют установить соединение или Сервер временно недоступен"); 
    Serial.println();    
  }
  http.end();                                     //Закрыть соединение 
}

void setup() {
  Serial.begin(115200);
  delay(10);
  WiFi.begin(ssid, password);
  period = Second * 1000;
}

void loop() {
  if (WiFi.status() != WL_CONNECTED) connectWiFi();   //Доступность сети         
  ejick(User, ID, Pas, String(sqrt(millis())));       //Отправляем на сервер
  while (millis() - myTimer1 < period) {              //Ожидание
      delay(100);
      /*
        *Здесь может располагаться Ваша функция управления вторичными устройствами
        *(другой шилд, двигатель, лампочка, ТЭН и т.п. через реле)
        *Функция будет выполнять команды в зависимости от показаний Вашего датчика
        *Алгоритм такой: По показаниям датчика даём сигнал на D2, который включит/выключит реле
        */
  }
  myTimer1 += period;                                 // сброс таймера 
}

Базовый MQTT

• Демонстрационный пример предназначен для работы ESP8266 (Nodemcu v3) с иммитацией датчика температуры. В примере шилд передаёт время своей работы (millis()). Замените на свои параметры. Подключение проверено на Arduino IDE 1.8.18, менеджер плат: Arduino core for ESP8266 WiFi chip v.3.0.2.

• Скопируйте в Вашу IDE и замените своими данными следующие переменные:
• ssid
• password
• User (Ваш логин)
• ID (Настройки -> ID контроллера)

• Pas (Настройки -> Пароль)

--------------------------->

#include <ESP8266WiFi.h>
#include <PubSubClient.h>               //by Nick O'Leary, v2.8.0

#define MSG_BUFFER_SIZE  (50)

WiFiClient espClient;
PubSubClient client(espClient);

const char* mqtt_server = "ejick.ru";       //Адрес сервера (не менять)
const char* ssid = "Name_WiFi";             //Имя Вашего WiFi
const char* password = "Password_WiFi";     //Пароль Вашего Wi-Fi 
const char* User = "UserName";              //Ваш логин на ejick.ru
const char* ID = "ID_Shield";               //Системный ID контроллера, см. Настройки -> ID контроллера
const char* Pas = "PasswordShield";         //Ваш пароль от контроллера, см. Настройки -> Пароль

const byte Second = 60;                     //Период отправки, секунд (не менее минуты)
char Topic[20] = "iot/";                    //Топик для публикации данных
char Error[20] = "err/";                    //Ответ сервера
uint32_t period = 0;
unsigned long lastMsg = 0;
char msg[MSG_BUFFER_SIZE];

void connectWiFi(){                         // Функция подключения к Wi-Fi
    WiFi.mode(WIFI_STA);
    WiFi.begin(ssid, password);
    Serial.println("Connecting to WiFi");
    while (WiFi.status() != WL_CONNECTED) {
      delay(500);
      Serial.println (millis());
    }
  Serial.print("Подключено к ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());
}  

void callback(char topic[20], byte* payload, unsigned int length) { //Ответ ejick
  Serial.print("Получено сообщение из [");
  Serial.print(topic);
  Serial.print("]: ");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }
  Serial.println();
}

void reconnect() {                          //Функция переподключения
  while (!client.connected()) {             //Если клиент отключен
    Serial.print("Attempting MQTT connection...");
    if (client.connect("", ID, Pas)) {      //Пытаемся подключиться
      Serial.println("подключено!");
      Serial.println("Ждём ...");
      client.subscribe(Error);
    }
    else {                                  //Если неудачно, печатаем ошибку:
      Serial.print("failed, rc=");                  //rc= -2: Неправильно настроено соединение
      Serial.print(client.state());                 //rc= -4: Неправильное имя или пароль
      Serial.println(" try again in 5 seconds");    //rc= -5: Ошибка авторизации
      delay(5000);                                  //Переподключение через 5с
    }
  }
}

void setup() {
  Serial.begin(115200);
  delay(500);
  connectWiFi();                            //Подключаемся к WiFi
  client.setServer(mqtt_server, 1883);      //Подключаемся к ejick.ru
  client.setCallback(callback);             //Подписываемся на сообщения
  period = Second * 1000;
  strcat(Topic, ID);                        //топик для отправки данных
  strcat(Error, ID);                        //топик для получения сообщений
}

void loop() {
  if (WiFi.status() != WL_CONNECTED) connectWiFi(); //Если пропала связь с WiFi, переподключаемся
  if (!client.connected())reconnect();              //Если пропала сязь с ejick.ru, переподключаемся
  client.loop();                                    //Устанавливаем слушателя
  unsigned long now = millis();
  if (now - lastMsg > period) {
    lastMsg = now;
    float temperature = sqrt(millis());             //Это тестовая функция
    /*
    * Вместо float temperature = sqrt(millis());    установите для передачи свои данные
    */
    Serial.println (temperature);
    strcat(msg, ID);                        //Собираем сообщение
    strcat(msg, "?");
    strcat(msg, User);
    strcat(msg, "?");
    char buffer[8];                         //Выделение памяти
    snprintf(buffer, sizeof buffer, "%.1f", temperature); //Форматируем данные датчика
    strcat(msg, buffer);                    //Готовим ответ
    Serial.print("Publish message: ");
    Serial.println(msg);
    client.publish(Topic, msg);             //Публикуем...
    msg[0] = '\0';                          //Обнуляем сообщение
  }
}

Безопасность

Этот раздел не может претендовать на всеобъемлющий инструктаж, однако, общие рекомендации такие
• 
  

• Никогда не передавайте критические данные, такие как пароли, логины, личные данные. Если информация не стоит потраченных усилий для её перехвата, то и заниматься этим никто не будет. Кому интересна температура воздуха в Вашем туалете ;)

• Не ставьте на исключительный контроль свои важные объекты, такие как охранные системы, температура инкубатора и т.п. Связь может исчезнуть и Вы рискуете потерять контроль. Пусть ejick только дублирует.

• Не доверяйте своим датчикам. Никому не доверяйте. Мне можно (с)

Палитра ошибок

При неудачных попытках записи, Ejick может вернуть такие ошибки:

• 01E: ...// Как правило, ошибка возникает при попытка аутентификации. Проверьте правильность данных шилда, логин, ID и пароль.

• 02E: ...// При попытках частой записи на сервер, Ejick выдаст предупреждение. При регулярном появлении такой ошибки, аккаунт может быть снесён автоматически.

• 08E: ...// Это не ошибка. В этом режиме для экономии ресурсов может быть отключен Диспетчер. Таким образом, работа с шилдом переходит в режим Parking. Это означает, что шилд будет продолжать запись на сервер, но отображение данных online будет ограничено. Ситуация возникает, когда аккаунт шилда нуждается в продлении. Запись данных и просмотр архивов останутся доступны.

• Прочие ошибки предполагают вмешательство Admin.

Рекомендации

• В любом случае, в первую очередь, проверьте правильность и корректность прошивки контроллера. Сравните с предоставленными в разделе "Примеры" базовыми ("нулевыми") скетчами. Попытайтесь подключиться к серверу. Если всё равно не получается, обращайтесь через систему тикетов ("Почта Ejick").

• Подавляющее большинство примеров, созданных ChatGPT, работают с Ejick со старта. Поэтому, пробуйте.